c  Simplified French keyboard, to allow accented vowels, without any
c  key reassignments.  Normal quote, caret and accent are used as deadkeys.
c
c  To produce a quote, caret or accent mark separately, hit the key twice.
c
c  Tilde also combines in the same way with a following vowel to produce the 
c  modified characters (e.g. nasal o, enye), but is not a deadkey.
c
c  To produce a vowel with an umlaut, type a preceding double quote. To 
c  produce a double quote followed by a vowel, type the double quote twice
c  before typing the vowel.
c
NAME "Simple French"

BITMAPS FrKey1 FrKey0

HOTKEY [SHIFT ALT K_F]

VERSION 3.0

begin > use(main)

store(vowel) "aeiouyAEIOUY"		c vowels that can be modified

store(vUmlaut) "äëïöüÿÄËÏÖÜY"		c not Y
store(vCirc)   "âêîôûyÂÊÎÔÛY"		c not y, Y
store(vGrave)  "àèìòùyÀÈÌÒÙY"		c not y, Y
store(vAcute)  "áéíóúýÁÉÍÓÚÝ"

store(tildeLtr)  "aonAON"
store(tildeChar) "ãõñÃÕÑ"

group(main) using keys

 + "'" > deadkey(1)
 + "`" > deadkey(2)
 + "^" > deadkey(3)
 '"' + '"' > deadkey(4) '"'

deadkey(1) + any(vowel) > index(vAcute,2)
deadkey(2) + any(vowel) > index(vGrave,2)
deadkey(3) + any(vowel) > index(vCirc,2)
deadkey(4) '"' + any(vowel) > '"' index(vowel,3)

'"'  + any(vowel) > index(vUmlaut,2)
c '""' + any(vowel) > '"' index(vowel,2)

"~"  + any(tildeLtr) > index(tildeChar,2)

deadkey(1) + "'" > "'"
deadkey(2) + "`" > "`"
deadkey(3) + "^" > "^"
deadkey(1) + "c" > d231
deadkey(1) + "C" > d199

"<" + "<" > d171
">" + ">" > d187
d171 + "<" > "<<" deadkey(5)
d187 + ">" > ">>" deadkey(5)
deadkey(5) + ">" > ">" deadkey(5)
deadkey(5) + "<" > "<" deadkey(5)

c ">>" + ">" > ">>>"
c "<<" + "<" > "<<<"

'??' + '?'  > d169 ' 1994 Tavultesoft'