c ====================================================================
c CNVRT-PD.CCT - Convert MDF paradigm forms to new format
c For Shoebox Test Version 3.09
c See the *** comments to learn how to modify this change table.
c --------------------------------------------------------------------
c 1997-10-03 Mark R. Pedrotti (ICTS Software Development)

begin >
    store(WS) ' ' nl d9 endstore  c White space: space, newline, tab
    store(Backslash) '\' endstore
    use(gMain)

c --------------------------------------------------------------------

c Example of converting an old paradigm form field:

c \pl asure

c To the new format:

c \pdl pl
c \pdv asure

c The paradigm form "bundle" of fields includes optional glosses
c in English, national, and regional languages, for example:

c \pdl pl
c \pdv asure
c \pde dogs
c \pdn anjing-anjing

c ***  Here you choose whether you want this change table to add
c any of these markers to your lexical database file for you to
c fill in later. By default none are added. To have any of the
c three markers below added, remove the c [comment] at the beginning
c of the line:

define(dRestOfBundle) >
    c '\pde' nl  c Paradigm form gloss (English)
    c '\pdn' nl  c Paradigm form gloss (national)
    c '\pdr' nl  c Paradigm form gloss (regional)
    if(nl) nl clear(nl) endif  c Data field ended with a blank line

c --------------------------------------------------------------------
group(gMain)

c Note: By default, this table uses the standard paradigm markers
c for the labels because they are familiar and easy to type.
c The mdf_eng.cct and national labels change tables then convert
c these internal data items to the standard printing labels.

c *** If you want to change the data items themselves (e.g. Pl instead
c of pl) while you change to the new format, modify the right-hand-side
c of the following rules. Make the corresponding modifications to the
c left-hand-side of the rules in group(gParadigmLabel) in the
c mdf_*.cct change tables you use for English and national audiences.

'\sg' fol(WS) > '\pdl sg' nl use(gAfterMarker)
'\pl' fol(WS) > '\pdl pl' nl use(gAfterMarker)
'\rd' fol(WS) > '\pdl rd' nl use(gAfterMarker)

'\1s' fol(WS) > '\pdl 1s' nl use(gAfterMarker)
'\2s' fol(WS) > '\pdl 2s' nl use(gAfterMarker)
'\3s' fol(WS) > '\pdl 3s' nl use(gAfterMarker)
'\4s' fol(WS) > '\pdl 4s' nl use(gAfterMarker)

'\1d' fol(WS) > '\pdl 1d' nl use(gAfterMarker)
'\2d' fol(WS) > '\pdl 2d' nl use(gAfterMarker)
'\3d' fol(WS) > '\pdl 3d' nl use(gAfterMarker)
'\4d' fol(WS) > '\pdl 4d' nl use(gAfterMarker)

'\1p' fol(WS) > '\pdl 1p' nl use(gAfterMarker)
'\1i' fol(WS) > '\pdl 1i' nl use(gAfterMarker)
'\1e' fol(WS) > '\pdl 1e' nl use(gAfterMarker)
'\2p' fol(WS) > '\pdl 2p' nl use(gAfterMarker)
'\3p' fol(WS) > '\pdl 3p' nl use(gAfterMarker)
'\4p' fol(WS) > '\pdl 4p' nl use(gAfterMarker)

'\' > dup use(gRestOfField)

c --------------------------------------------------------------------
group(gAfterMarker)

nl nl fol(Backslash) > set(nl) next
nl fol(Backslash) > '\pdv' nl do(dRestOfBundle) use(gMain)  c Empty

endfile > next
nl endfile > '\pdv' nl do(dRestOfBundle) endfile  c Empty field

any(WS) > ''

'' > '\pdv ' use(gParadigmForm)

c --------------------------------------------------------------------
group(gParadigmForm)

nl nl fol(Backslash) > set(nl) next
nl fol(Backslash) > nl do(dRestOfBundle) use(gMain)

endfile > next
nl endfile > nl do(dRestOfBundle) endfile

c --------------------------------------------------------------------
group(gRestOfField)

nl fol(Backslash) > dup use(gMain)